步骤 11：添加导出配置

在教程的 [`Installing and Testing`](Installing%20and%20Testing.html#guide:tutorial/Installing%20and%20Testing "tutorial/Installing and Testing") 部分中，我们添加了使 CMake 能够安装项目的库和头文件的功能。在 [`Packaging an Installer`](Packaging%20an%20Installer.html#guide:tutorial/Packaging%20an%20Installer "tutorial/Packaging an Installer") 部分中，我们添加了将这些信息打包起来以便分发给其他人的功能。

接下来的步骤是添加必要的信息，以便其他 CMake 项目可以使用我们的项目，无论是来自构建目录、本地安装还是打包后。

第一步是更新我们的 [`install(TARGETS)`](../../command/install.html#targets "install(targets)") 命令，不仅指定 `DESTINATION`，还指定 `EXPORT`。`EXPORT` 关键字生成一个包含从安装目录树中的所有目标列表中列出的所有目标的导入代码的 CMake 文件。因此，让我们继续通过更新 `MathFunctions/CMakeLists.txt` 中的 `install` 命令，明确地将 `MathFunctions` 库导出：

```cmake
# MathFunctions/CMakeLists.txt

set(installable_libs MathFunctions tutorial_compiler_flags)
if(TARGET SqrtLibrary)
  list(APPEND installable_libs SqrtLibrary)
endif()
install(TARGETS ${installable_libs}
        EXPORT MathFunctionsTargets
        DESTINATION lib)
# install include headers
install(FILES MathFunctions.h DESTINATION include)
```

现在我们已经导出了 `MathFunctions`，我们还需要明确安装生成的 `MathFunctionsTargets.cmake` 文件。通过在顶层 `CMakeLists.txt` 的底部添加以下内容来实现：

```cmake
# CMakeLists.txt

install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)
```

此时，你应该尝试运行 CMake。如果一切设置正确，你将看到 CMake 生成的一个错误，看起来像是：

```
Target "MathFunctions" INTERFACE_INCLUDE_DIRECTORIES property contains
path:

"/Users/robert/Documents/CMakeClass/Tutorial/Step11/MathFunctions"

which is prefixed in the source directory.
```

CMake 要表达的意思是，在生成导出信息时，它将导出一个与当前计算机密切相关的路径，这在其他计算机上无效。解决此问题的方法是更新 `MathFunctions` 的 [`target_include_directories()`](../../command/target_include_directories.html#command:target_include_directories "target_include_directories")，以理解在从构建目录和从安装/打包中使用时需要不同的 `INTERFACE` 位置。这意味着将 `MathFunctions` 的 [`target_include_directories()`](../../command/target_include_directories.html#command:target_include_directories "target_include_directories") 调用转换为以下方式：

```cmake
# MathFunctions/CMakeLists.txt

target_include_directories(MathFunctions
                           INTERFACE
                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
                            $<INSTALL_INTERFACE:include/>
                           )
```

更新后，我们可以重新运行 CMake 并验证它不再报警。

此时，我们已经正确地打包了所需的目标信息，但我们仍然需要生成一个 `MathFunctionsConfig.cmake`，以便 CMake 的 [`find_package()`](../../command/find_package.html#command:find_package "find_package") 命令可以找到我们的项目。因此，让我们继续并在项目的顶层添加一个名为 `Config.cmake.in` 的新文件，其内容如下：

```cmake
# Config.cmake.in

@PACKAGE_INIT@

include ( "${CMAKE_CURRENT_LIST_DIR}/MathFunctionsTargets.cmake" )
```

然后，为了正确配置和安装该文件，将以下内容添加到顶层 `CMakeLists.txt` 的底部：

```cmake
# CMakeLists.txt

install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)

include(CMakePackageConfigHelpers)
# generate the config file that includes the exports
configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
  INSTALL_DESTINATION "lib/cmake/MathFunctions"
  NO_SET_AND_CHECK_MACRO
  NO_CHECK_REQUIRED_COMPONENTS_MACRO
)
```

接下来，执行 [`configure_package_config_file()`](../../module/CMakePackageConfigHelpers.html#command:configure_package_config_file "configure_package_config_file")。这个命令将使用一些特定的区别于标准 [`configure_file()`](../../command/configure_file.html#command:configure_file "configure_file") 的方法来配置提供的文件。为了正确利用此函数，输入文件应该有一行文本 `@PACKAGE_INIT@`，除了所需的内容之外。该变量将被替换为一段代码，将设置的值转换为相对路径。这些新的值可以通过相同的名称引用，但前面加上 `PACKAGE_` 前缀。

接下来是 [`write_basic_package_version_file()`](../../module/CMakePackageConfigHelpers.html#command:write_basic_package_version_file "write_basic_package_version_file")。这个命令将写入一个文件，该文件由 [`find_package()`](../../command/find_package.html#command:find_package "find_package") 使用，记录所需包的版本和兼容性。在这里，我们使用 `Tutorial_VERSION_*` 变量，并声明它与 `AnyNewerVersion` 兼容，这表示这个版本或任何更高版本都与请求的版本兼容。

```cmake
# CMakeLists.txt

write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
  VERSION "${Tutorial_VERSION_MAJOR}.${Tutorial_VERSION_MINOR}"
  COMPATIBILITY AnyNewerVersion
)
```

最后，将生成的两个文件都设置为要安装：

```cmake
# CMakeLists.txt

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake
  DESTINATION lib/cmake/MathFunctions
)
```

此时，我们已经生成了一个可移植的 CMake