步骤 4：添加生成器表达式

# Step 4: Adding Generator Expressions

`生成器表达式` 在构建系统生成期间计算，以生成特定于每个构建配置的信息。

`生成器表达式`] 允许在许多目标属性的上下文中使用，例如 `LINK_LIBRARIES`, `INCLUDE_DIRECTORIES`, `COMPILE_DEFINITIONS` 等。它们还可以在使用命令填充这些属性时使用，例如 `target_link_libraries()`, `target_include_directories()`, `target_compile_definitions()` 等。

`生成器表达式` 可用于启用条件链接、编译时使用的条件定义、条件包含目录等。条件可以基于构建配置、目标属性、平台信息或任何其他可查询的信息。

有不同类型的 `生成器表达式`，包括逻辑表达式、信息表达式和输出表达式。

逻辑表达式用于创建条件输出。基本表达式是 `0` 和 `1` 表达式。`$<0:...>` 生成空字符串，`$<1:...>` 生成 `...` 的内容。它们也可以嵌套使用。

## Exercise 1 - 使用生成器表达式添加编译器警告标志

`生成器表达式` 的常见用法之一是有条件地添加编译器标志，例如语言级别或警告。一个不错的模式是将这些信息关联到一个`INTERFACE`目标，使得这些信息能够传播。

### Goal

构建时添加编译器警告标志，但在安装版本中不添加。

### Helpful Resources

+   `cmake-generator-expressions(7)`
+   `cmake_minimum_required()`
+   `set()`
+   `target_compile_options()`

### Files to Edit

+   `CMakeLists.txt`

### Getting Started

打开文件 `Step4/CMakeLists.txt` 并完成 `TODO 1` 到 `TODO 4`。

首先，在顶层的 `CMakeLists.txt` 文件中，我们需要将 `cmake_minimum_required()` 设置为 `3.15`。在这个练习中，我们将使用在 CMake 3.15 中引入的生成器表达式。

接下来，我们添加我们项目所需的编译器警告标志。由于警告标志根据编译器而异，我们使用 `COMPILE_LANG_AND_ID` 生成器表达式来控制在给定语言和一组编译器标识的情况下应用哪些标志。

### Build and Run

创建一个名为 `Step4_build` 的新目录，运行 `cmake` 可执行文件或 `cmake-gui` 来配置项目，然后使用你选择的构建工具构建项目，或者在构建目录中使用 `cmake --build .` 进行构建。

```bash
mkdir Step4\_build
cd Step4\_build
cmake ../Step4
cmake --build .
```

### Solution

更新 cmake_minimum_required()，要求至少需要 CMake 版本 3.15：

#### TODO 1: CMakeLists.txt

```cmake
cmake_minimum_required(VERSION 3.15)
```

接下来，我们确定当前系统正在使用的编译器来构建，因为警告标志根据我们使用的编译器而变化。这可以通过 `COMPILE_LANG_AND_ID` 生成表达式来实现。我们将结果分别设置为变量 `gcc_like_cxx` 和 `msvc_cxx`，如下所示：

#### TODO 2: CMakeLists.txt

```cmake
set(gcc_like_cxx "$<COMPILE_LANG_AND_ID:CXX,ARMClang,AppleClang,Clang,GNU,LCC>")
set(msvc_cxx "$<COMPILE_LANG_AND_ID:CXX,MSVC>")
```

接下来，我们添加我们项目所需的所需的编译器警告标志。使用我们的变量 `gcc_like_cxx` 和 `msvc_cxx`，我们可以使用另一个生成表达式仅在这些变量为真时应用相应的标志。我们使用 `target_compile_options()` 将这些标志应用到我们的接口库。

#### TODO 3: CMakeLists.txt

```cmake
target_compile_options(tutorial_compiler_flags INTERFACE
  "$<${gcc_like_cxx}:-Wall;-Wextra;-Wshadow;-Wformat=2;-Wunused>"
  "$<${msvc_cxx}:-W3>"
)
```

最后，我们只希望在构建过程中使用这些警告标志。我们安装的项目的消费者不应该继承我们的警告标志。为了指定这一点，我们使用 `BUILD_INTERFACE` 条件将我们在 TODO 3 中的标志包裹在生成表达式中。最终的完整代码如下所示：

#### TODO 4: CMakeLists.txt

```cmake
target_compile_options(tutorial_compiler_flags INTERFACE
  "$<${gcc_like_cxx}:$<BUILD_INTERFACE:-Wall;-Wextra;-Wshadow;-Wformat=2;-Wunused>>"
  "$<${msvc_cxx}:$<BUILD_INTERFACE:-W3>>"
)
```