步骤 10：选择静态库或共享库

# 第10步：选择静态库或共享库

在本节中，我们将展示如何使用 [`BUILD_SHARED_LIBS`](../../variable/BUILD_SHARED_LIBS.html#variable:BUILD_SHARED_LIBS "BUILD_SHARED_LIBS") 变量来控制 [`add_library()`](../../command/add_library.html#command:add_library "add_library") 的默认行为，并允许控制没有明确类型（`STATIC`、`SHARED`、`MODULE` 或 `OBJECT`）的库的构建方式。

为了实现这一点，我们需要在顶级 `CMakeLists.txt` 中添加 [`BUILD_SHARED_LIBS`](../../variable/BUILD_SHARED_LIBS.html#variable:BUILD_SHARED_LIBS "BUILD_SHARED_LIBS")。我们使用 [`option()`](../../command/option.html#command:option "option") 命令，因为它允许用户选择值是否为 `ON` 或 `OFF`。

```cmake
# CMakeLists.txt

option(BUILD_SHARED_LIBS "Build using shared libraries" ON)
```

接下来，我们需要为我们的静态库和共享库指定输出目录。

```cmake
# CMakeLists.txt

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
```

最后，更新 `MathFunctions/MathFunctions.h` 来使用 dll 导出定义：

```cpp
// MathFunctions/MathFunctions.h

#if defined(_WIN32)
#  if defined(EXPORTING_MYMATH)
#    define DECLSPEC __declspec(dllexport)
#  else
#    define DECLSPEC __declspec(dllimport)
#  endif
#else // non windows
#  define DECLSPEC
#endif

namespace mathfunctions {
double DECLSPEC sqrt(double x);
}
```

此时，如果你构建所有内容，你可能会注意到链接失败，因为我们将没有位置独立代码的静态库与具有位置独立代码的库组合在一起。解决此问题的方法是在构建共享库时，将 SqrtLibrary 的 [`POSITION_INDEPENDENT_CODE`](../../prop_tgt/POSITION_INDEPENDENT_CODE.html#prop_tgt:POSITION_INDEPENDENT_CODE "POSITION_INDEPENDENT_CODE") 目标属性显式设置为 `True`。

```cmake
# MathFunctions/CMakeLists.txt

# state that SqrtLibrary need PIC when the default is shared libraries
set_target_properties(SqrtLibrary PROPERTIES
                      POSITION_INDEPENDENT_CODE ${BUILD_SHARED_LIBS}
                      )
```

定义 `EXPORTING_MYMATH` 表示在 Windows 上构建时我们正在使用 `declspec(dllexport)`。

```cmake
# MathFunctions/CMakeLists.txt

# define the symbol stating we are using the declspec(dllexport) when
# building on windows
target_compile_definitions(MathFunctions PRIVATE "EXPORTING_MYMATH")
```

**练习**：我们修改了 `MathFunctions.h` 来使用 dll 导出定义。使用 CMake 文档，你能找到一个简化此过程的辅助模块吗？